@echo off
setlocal

set VERSION=1.0.0
for /f "tokens=2 delims==" %%I in ('wmic os get localdatetime /value') do set datetime=%%I
set BUILD_TIME=%datetime:~0,4%-%datetime:~4,2%-%datetime:~6,2% %datetime:~8,2%:%datetime:~10,2%:%datetime:~12,2%
set LDFLAGS=-s -w -X "main.Version=%VERSION%" -X "main.BuildTime=%BUILD_TIME%"

echo.
echo  Building Server...
mkdir dist\server\data 2>nul
set GOOS=windows&& set GOARCH=amd64&& go build -ldflags "%LDFLAGS%" -o dist\server\monitor-server.exe .\cmd\server
if %errorlevel% neq 0 (
    echo  [ERROR] Server build failed!
    pause
    exit /b 1
)

echo  Building Client...
mkdir dist\client 2>nul
set GOOS=windows&& set GOARCH=amd64&& go build -ldflags "%LDFLAGS%" -o dist\client\monitor-client.exe .\cmd\client
if %errorlevel% neq 0 (
    echo  [ERROR] Client build failed!
    pause
    exit /b 1
)

echo.
echo  ===================================================
echo   Server: dist\server\monitor-server.exe
echo   Client: dist\client\monitor-client.exe
echo  ===================================================
echo.
echo  Server 分发: 复制 dist\server\ 整个文件夹
echo  Client 分发: 复制 dist\client\ 整个文件夹
echo.
pause